You are here: Home / Extra / Calcolo con formule / Utilizzo per contatti e immobili

Calcolo con formule

Utilizzo per contatti e immobili

Calcolare (matematica)

Una formula di calcolo inizia sempre con un segno di uguale “=”, come molti sanno da Excel. Se si desidera utilizzare il valore di un campo per il calcolo, è necessario inserire il nome del campo tra parentesi quadre.
Si noti che se si lavora con numeri decimali nell’editor di formule, la virgola “,” deve essere scritta come un punto “.”
. Ecco un esempio: =[kaltmiete]+[nebenkosten]+[ind_1078_Feld_ObjPreise33]+3.57

Il nome del campo non è quello visualizzato nel software, ma la voce nella colonna Campo. Il nome lungo “ind…” è il nome di un campo individuale. È quindi possibile inserire formule per i campi di sistema e per i campi creati dall’utente.

Ci sono le operazioni aritmetiche di base (+ – * /) e vale la regola moltiplicazione e divisione prima di addizione e sottrazione. Come caso speciale, c’è_calculate.
È possibile utilizzare tutti i campi numerici e anche i campi checkbox per il calcolo. Si tratta di campi di tipo Decimal, Float, Integer, Int, TINYINT e Boolean.

_calculate

L’elemento formula _calculate è una macro. Si può usare la macro _calculate per calcolare valori basati su valori dei campi. A tal fine, viene utilizzata una formula logica come parametro.
Struttura della formula: _calculate(text(DATEADD(today();10;"d");"DD.MM.YYYY"))
Esempi: _calculate([kaufpreis]*3) o _calculate(IF([kaufpreis]<1000000;[kaufpreis]*3;[kaufpreis]*4))

Le formule sono un elemento pratico che si può utilizzare anche nelle macro, in particolare nelle “macro if”. Per fare ciò, è necessario includere anche la formula o il valore del campo nella macro_calculate().

Esempio: _if(_calculate[kaufpreis]<1000000;”_kaufpreis”;”Preis auf Anfrage”)

La macro _calculate produce i valori in formato inglese, con un punto come separatore decimale. Per visualizzare i valori nella formattazione tedesca con una virgola come separatore decimale, utilizzare il parametro FIXED. FIXED può essere utilizzato anche per determinare il numero di cifre decimali.

Esempi:

_calculate([kaufpreis]) -> 233333.00
_calculate(FIXED([kaufpreis])) -> 233.333,00
_calculate(FIXED([kaufpreis];0)) -> 233.333

Funzioni

Le funzioni di formula consentono, ad esempio, di calcolare un valore medio da diversi campi numerici o di abbreviare i campi di testo. Attualmente esistono quattro aree diverse che possono essere modificate tramite le funzioni. Questi sono:

  1. Funzioni di testo
  2. Funzioni numeriche
  3. Funzioni data
  4. Funzioni logiche

Per creare una funzione formula, andare su Extra>> Impostazioni >> Amministrazione >> Campi di inserimento, selezionare il modulo e la categoria pertinenti e creare un nuovo campo personalizzato in cui memorizzare una funzione formula.

1. Funzioni di testo

Le funzioni di testo consentono di abbreviare i campi di testo o di cercare parole specifiche, stringhe di caratteri o simili. Sono disponibili 7 funzioni di testo e un nuovo operatore di testo”&“, che può essere utilizzato per collegare i campi di testo. Di seguito sono riportate le rispettive formule con esempi. Tutti gli esempi si riferiscono al campo “titolo dell’immobile” con il contenuto “terreno pianeggiante e ricoperto di verde”.

  • LENGTH:
     è possibile utilizzare la formula LENGTH per visualizzare la lunghezza del contenuto di un campo di testo.
    Il risultato viene emesso come numero intero. Struttura della formula: LENGTH([Feldname])
    Esempio: LENGTH([objekttitel])
    Viene emessa la lunghezza del titolo dell’immobile. Risultato: 26
  • LEFT:
    È possibile utilizzare la formula LEFT per emettere un certo numero di caratteri da sinistra.
    Questo viene fatto in forma di testo. Struttura della formula: LEFT([Feldname];Anzahl Zeichen)
    Esempio: LEFT([objekttitel];5)
    Vengono emessi i primi 5 caratteri del titolo dell’immobile. Risultato: Terreno
  • RIGHT:
    La formula RIGHT è l’opposto della formula LEFT.
    La modalità di funzionamento è la stessa. Struttura della formula: RIGHT([Feldname];Anzahl Zeichen)
    Esempio: RIGHT([objekttitel];10)
    Vengono emessi 10 caratteri da destra. Risultato: Terreno
  • MID:
    è possibile utilizzare la formula MID per emettere testo dal centro.
    Struttura della formula: MID([Feldname];Erstes Zeichen;Anzahl Zeichen)
    Esempio: MID([objekttitel];7;9)
    Dal 7° carattere in poi, vengono emessi i 9 caratteri successivi. Risultato: pianeggiante
  • SEARCH:
    è possibile utilizzare SEARCH per cercare termini, stringhe di caratteri e spazi in un campo di testo.
    Struttura della formula: SEARCH("Suchbegriff";[Feldname];Optional: Erstes Zeichen)
    Esempio: SEARCH(" ";[objekttitel])
    Il sistema cerca il primo spazio nel titolo dell’immobile. Risultato: 6
    Esempio: SEARCH(" ";[objekttitel];7)
    Dal 7° carattere in poi, il sistema cerca lo spazio successivo. Risultato: 16
  • SEARCH_MULTISELECT:
    è possibile utilizzare SEARCH_MULTISELECT per cercare i valori in un campo selezione multipla.
    Struttura della formula: SEARCH_MULTISELECT("Suchbegriff";[Feldname des Multiselectfeldes])
    Esempio: SEARCH_MULTISELECT("lasten";[fahrstuhl])
    Viene effettuata una ricerca per il valore multiselezione “lasten”, ovvero il sollevamento merci, nel campo selezione multipla “fahrstuhl”.
    Risultato:  0 se il “termine di ricerca” non è stato trovato (cioè = il valore non è incluso). A seconda del tipo di dati del campo, lo 0 non viene visualizzato nell’interfaccia grafica, ma il campo rimane vuoto.
    Risultato: 0 se non è stato specificato alcun campo selezione multipla per [Nome del campo selezione multipla]. A seconda del tipo di dati del campo, lo 0 non viene visualizzato nell’interfaccia grafica, ma il campo rimane vuoto.
    Risultato: 1, se il “termine di ricerca” è stato trovato (cioè “il valore è contenuto”).
  • TRIM :
    TRIM consente di “tagliare” gli spazi prima e dopo il testo. Poiché tutti i campi di testo in onOffice enterprise vengono tagliati fin dall’inizio, l’esempio consiste in una funzione formula composita.
    Struttura della formula: TRIM([nome del campo])
    Esempio: TRIM(MID([objekttitel];6;11))
    Per prima cosa, “verde” viene tagliato dal titolo dell’immobile utilizzando la funzione MID e gli spazi del prefisso e del suffisso vengono rimossi utilizzando TRIM. Risultato: “verde”
  • TEXT:
    è possibile utilizzare la funzione TEXT per visualizzare un campo data come testo, ad esempio. Nell’esempio, viene utilizzato il campo data [erstellt_am]. Questo campo viene creato al momento della creazione dell’immobile e non può essere modificato. Esempio 19/02/2017
    Struttura della formula: TEXT([nome del campo]; “TEXT”)
    Esempio: TEXT([erstellt_am];"DD/MM/YY") Questa formula produce il campo data in una notazione diversa, basata sulla macro _Datum.
    Risultato: 19/02/17
  • “&” :
    “&” : può essere utilizzato per collegare tra loro diversi campi di testo o campi numerici, ad esempio.
    Struttura della formula: [Feldname]&[Feldname] oder [Feldname]&"Text"
    Esempio: [objekttitel]&" "&[objekttitel] emette il titolo dell’immobile due volte in successione, separate da uno spazio.
    Risultato: terreno pianeggiante e ricoperto di verde terreno pianeggiante e ricoperto di verde

2. Numeri Funzioni

È possibile utilizzare le funzioni numeriche per calcolare un valore medio da diversi campi numerici o per arrotondare i valori numerici. Sono disponibili 5 funzioni numeriche. Di seguito troverai la rispettiva formula con esempi. Tutti gli esempi si riferiscono al campo “Prezzo d’acquisto” con il valore 162.990,35. Per calcolare il valore medio, si aggiunge il campo “Valore di mercato” con il valore 170.000,00 .

  • ROUNDUP:
    la formula ROUNDUP può essere utilizzata per arrotondare un valore.
    Struttura della formula: ROUNDUP([nome del campo];numero di cifre decimali da arrotondare)
    Esempio: ROUNDUP([kaufpreis];1)
    Il prezzo di acquisto viene arrotondato a una cifra decimale. Risultato: 162.990,40
  • ROUNDDOWN:
    la formula ROUNDDOWN può essere utilizzata per arrotondare i campi numerici.
    Struttura della formula: ROUNDDOWN([Feldname];Anzahl Nachkommastellen, welche gerundet werden)
    Esempio: ROUNDDOWN([kaufpreis];1) Il prezzo di acquisto viene arrotondato alla prima cifra decimale.
    Risultato: 162.990,30
  • ROUND :
    La formula ROUND viene utilizzata per gli arrotondamenti commerciali.
    Struttura della formula: ROUND([Feldname];Anzahl der zu rundenden Nachkommastellen)
    Esempio: ROUND([kaufpreis];1) Il risultato viene arrotondato a una cifra decimale.
    Risultato: 162.990,40
  • FIXED:
    è possibile utilizzare la formula FIXED per accorciare i numeri di cifre decimali o per produrre più cifre decimali. Si noti che la formula FIXED può essere utilizzata solo in un campo di testo e non è quindi possibile continuare a calcolare con il risultato. FIXED produce anche il valore nella formattazione tedesca con una virgola come separatore decimale.
    Struttura della formula: FIXED([Feldname];Anzahl der Nachkommastellen welche ausgegeben werden sollen)
    Esempio: FIXED([kaufpreis];4) Vengono emesse in totale 4 cifre decimali.
    Risultato: 162.990.3500
    Esempio: FIXED([kaufpreis];0) Il prezzo di acquisto non contiene cifre decimali.
    Risultato: 162.990
  • AVERAGE:
    è possibile utilizzare AVERAGE per calcolare un valore medio di due o più campi numerici.
    Struttura della formula: AVERAGE([Feldname];[Feldname2])
    Esempio: AVERAGE([kaufpreis];[verkehrswert]) Si determina il valore medio dei due campi numerici prezzo di acquisto e valore di mercato.
    Risultato: 166.495,18
    Calcolatore dei risultati: 166.495,175
  • SUM:
    è possibile utilizzare la formula SUM per calcolare la somma di più campi singoli.
    Struttura della formula: SUM([Feldname1];[Feldname2];[Feldname3])
    Esempio:
    Risultato: 332.990,35
  • MIN:
    la formula MIN può essere utilizzata per determinare il valore minimo da un insieme di valori.
    Struttura della formula: MIN([Feldname1];[Fendname2];[Feldname3]) viene emesso il valore più basso tra i 3 campi.
    Esempio: MIN([kaufpreis];[verkehrswert]) Viene calcolato il valore minimo del prezzo di acquisto e il valore di mercato dell’immobile.
    Risultato: 162.990,35
  • MAX :
    utilizzando la formula MAX, è possibile determinare il valore massimo da un insieme di valori.
    Struttura della formula: MAX([Feldname1];[Feldname2];[Feldname3])
    viene emesso il valore più alto tra i 3 campi. Esempio: MAX([kaufpreis];[verkehrswert])
    Risultato: 170.000,00
  • POWER:
    la funzione POWER può essere utilizzata per calcolare potenze.
    Struttura della formula: POWER([Feldname1];[Feldname2]) o. POWER(Zahl1;Zahl2)
    Il primo parametro specifica la base, il secondo l’esponente. Esempio: POWER(5;2)
    Risultato: 25
  • LOG:
    La funzione LOG può essere utilizzata per calcolare i logaritmi.
    Struttura della formula: LOG([Feldname1];[Feldname2]) oder LOG(Zahl;Basis). Il primo parametro specifica il logaritmo, il secondo la base.
    Il secondo parametro base è opzionale.LOG(numero) calcola il logaritmo naturale senza specificare una base. Esempio: LOG(64;2)
    Risultato: 6

3. Funzioni data

Un’altra area di applicazione delle funzioni formula sono i campi data. Qui è possibile visualizzare l’ora tra due date o aggiungere un numero definito di giorni, mesi o anni a una data. È possibile utilizzare un totale di 5 formule diverse. Per tutti gli esempi viene utilizzato il campo “creato il” con il valore 09/02/2017. Per gli esempi in cui viene calcolato l’intervallo di tempo tra due date, il campo “Incarico fino a” viene aggiunto con il valore 01.03.2019. Oggi è il 01.03.2017.

Si noti che le funzioni di data vengono sempre emesse nel formato YYYY-MM-DD e possono calcolare solo in questo formato. La funzione TEXT consente di ottenere una visualizzazione diversa. Esempio: _calculate(text(DATEADD(today();10;”d”);”DD.MM.YYYY”))

  • TODAY:
    la formula OGGI può essere utilizzata per produrre la data odierna.
    Struttura della formula: TODAY()
    Esempio: TODAY()
    Viene visualizzata la data odierna. Risultato: 24/06/2021
  • NOW:
    la formula ORA può essere utilizzata per visualizzare la data e l’ora di oggi.
    Struttura della formula: NOW()
    Esempio: NOW() Vengono visualizzate la data e l’ora di oggi.
    Risultato: 2021-06-24 12:07:40
  • WEEKDAY:
    la formula WEEKDAY può essere utilizzata per ottenere il giorno della settimana di un campo data.
    Struttura della formula: WEEKDAY([Feldname])
    Esempio: WEEKDAY([erstellt_am])
    Il giorno della settimana del campo “creato il” viene visualizzato nel campo. Risultato: Giovedì
  • MONTH:
    la formula MONTH indica il mese del campo da calcolare.
    Struttura della formula: MONTH([Feldname])
    Esempio: MONTH([erstellt_am])
    Il mese del campo “creato il” viene visualizzato nel campo. Risultato: Febbraio
  • DATEADD:
    è possibile utilizzare la formula DATEADD per aggiungere un numero di giorni, mesi o anni a un campo data utilizzando un parametro (d, m o y).
    Struttura della formula: DATEADD([Feldname];Anzahl;"Parameter")
    Esempio: DATEADD([erstellt_am];13;"d")
    13 giorni vengono aggiunti alla data di “creazione”. Risultato: 22.02.2017
    Esempio: DATEADD([erstellt_am];2;"m")
    La data “creata il” più 2 mesi. Risultato: 09.04.2017
    Esempio: DATEADD([erstellt_am];1;"y")
    Si aggiunge un anno. Risultato: 09/02/2018
  • DATEDIF:
    è possibile utilizzare DATEDIF per ottenere l’intervallo di tempo tra due campi data in giorni (d), mesi (m) o anni (y).
    Struttura della formula: DATEDIF([Feldname];[Feldname2];"Parameter")
    Esempio: DATEDIF([erstellt_am];[auftragbis];"d") L’intervallo di tempo tra “creato il” e “ordinato a” viene visualizzato in giorni.
    Risultato: 750
    Esempio: DATEDIF([erstellt_am];[auftragbis];"m")
    I mesi tra le due date vengono emessi. Risultato: 24
    Esempio: DATEDIF([erstellt_am];[auftragbis];"y")
    Gli anni tra le due date devono essere visualizzati. Risultato: 2
  • TEXT:
    è possibile utilizzare la funzione TEXT per visualizzare un campo data come testo, ad esempio. Nell’esempio, viene utilizzato il campo data [erstellt_am]. Questo campo viene creato al momento della creazione dell’immobile e non può essere modificato. Esempio 19/02/2017
    Struttura della formula: TEXT([nome del campo]; “Text”)
    Esempio: TEXT([erstellt_am];"DD/MM/YY") Questa formula produce il campo data in una notazione diversa, basata sulla macro _Datum.
    Risultato: 19/02/17

4. Funzioni logiche

Logica IF

È anche possibile includere query IF. Tutti i campi (compresi i campi di testo o i campi chiave) possono essere utilizzati come condizione. La sintassi si basa sulla funzione Excel “If()”: IF(Bedingung wahr;Dann;Sonst).
Il valore del campo in cui è stata inserita la formula viene riempito con il contenuto della condizione Then o Else . Ecco un esempio: IF([Feldname1]>0;[Feldname2]+[Feldname3];[Feldname4]+[Feldname8]).

Per controllare i campi chiave (campi a selezione singola o multipla), è necessario verificare la selezione del campo chiave nella condizione.
Un esempio di campi a selezione singola: IF([Schlüsselfeld]="Feld";Dann;Sonst).
Un esempio di campi selezione multipla: IF(SEARCH_MULTISELECT("Suchbegriff";[Feldname des Multiselectfeldes])=1;Dann;Sonst).

Logica AND/OR

È possibile utilizzare anche condizioni come AND/OR . Ciò consente di utilizzare la condizione AND, ad esempio, per specificare che un risultato viene inserito nel campo della formula solo dopo che le condizioni AND sono state risolte. Con la condizione OR, è sufficiente che uno dei parametri interrogati sia corretto.

  • AND:
    Struttura della formula: AND([Feldname];[Feldname])
    Struttura della formula composita: IF(AND([Feldname]="Feldparameter1";[Feldname2]="Feldparameter2");"Ausgabe1";"Ausgabe2")
    In questo caso, le formule vengono risolte dall’interno. Ciò significa che “Parametro campo1” viene emesso solo se i parametri del campo1 e del campo2 sono corretti.
    Se i parametri non corrispondono a quelli predefiniti, viene generato “Output2”
    Esempio: IF(AND([vermarktungsart]="kauf";[objektart]="grundstueck");"Grundstück zu verkaufen";"")
    Risultato: Caso 1: Il tipo di commercializzazione e la tipologia di immobile corrispondono alle specifiche.
    Il campo è riempito con “Immobile in vendita”. Risultato: Caso 2: Nessuna o una sola corrispondenza. In questo caso, viene visualizzato l’output2, ovvero un campo vuoto.
  • OR:
    Struttura della formula: OR([nome del campo1];[nome del campo2])
    Struttura della formula composta: IF(OR([Feldname1]="Feldparameter1";[Feldname2]="Feldparameter2");"Ausgabe1";"Ausgabe2")
    Anche in questo caso, la formula viene risolta dall’interno. Se il parametro di campo1 o il parametro di campo2 sono corretti, si ottiene l’uscita “Output1”. Se né il primo né il secondo parametro sono corretti, il risultato è “Output2”.
    Esempio: IF(OR([newsletter_aktiv]="0";[newsletter_aktiv]="2");"Keinen Newsletter senden";"")
    Risultato caso 1:
    Se il campo di selezione singola Newsletter è riempito con No (0) o Cancellazione (2), viene visualizzato il testo “Non inviare la newsletter”. Risultato caso 2: Se viene impostato un valore diverso, il campo non viene visualizzato.

Logica NOT

È possibile utilizzare la logica NOT, ad esempio, per escludere il contenuto di uno o più campi e influenzare così il risultato. Ciò significa che i contenuti dei campi non menzionati nel NOT portano a un risultato.

  • NOT :
    Struttura della formula: NOT([Feldname1]="Feldparameter");"Ausgabe"
    Struttura della formula composita: IF(NOT([Feldname1]="Feldparameter1");"Ausgabe1")

Esempi dal nostro lavoro quotidiano

Si desidera estrarre singole parole da un campo composto da due o tre parole. Un esempio potrebbe essere il saluto, il nome e il cognome. Si noti che le formule elencate di seguito funzionano solo con tre parole nel campo.

Prima parola:
=LEFT([Feld mit Wörtern];SEARCH(" ";[Feld mit Wörtern];1))
Per spiegare: la formula viene utilizzata per cercare il primo spazio da sinistra. Tutto ciò che si trova a sinistra dello spazio viene inserito nel campo della formula.

Seconda parola:
=MID([Feld mit Wörtern];SEARCH(" "; [Feld mit Wörtern]; 1) + 1;SEARCH(" "; [Feld mit Wörtern]; SEARCH(" "; [Feld mit Wörtern];1) + 1)-SEARCH(" "; [Feld mit Wörtern];1))

Terza parola:
=RIGHT([Feld mit Wörtern];LENGTH([Feld mit Wörtern])-SEARCH(" ";[Feld mit Wörtern];SEARCH(" ";[Feld mit Wörtern];1)+1))

Calcolo con formule